Stacked Bar Chart

This example demonstrates creating a stacked bar chart, completed with bar labels and legend box.

The key features demonstrated in this example are:

Add a legend to the chart using BaseChart.addLegend.
The legend box is configured to have no border by setting the border color to transparent using Box.setBackground.
By default, the legend icon has a black border. This is to allow white or light color icons to be more visible on a white background. In this example, no such colors are used, and the icon border is disabled by setting its color to the same as the icon fill color. This is by using LegendBox.setKeyBorder with SameAsMainColor.
Add a stacked bar layer using XYChart.addBarLayer2 with the Stack predefined constant.
Add multiple data sets to the bar layer using Layer.addDataSet.
Add labels to the whole bar using Layer.setAggregateLabelStyle.
Add labels to the bar segments within a stacked bar using Layer.setDataLabelStyle.

For bar labels, Layer.setDataLabelStyle and Layer.setAggregateLabelStyle control the styles (fonts, colors, backgrounds, etc), while Layer.setDataLabelFormat and Layer.setAggregateLabelFormat control the formats (the label text, number of decimal points, etc). You can also add custom labels to the bars using Layer.addCustomDataLabel, Layer.addCustomAggregateLabel and Layer.addCustomGroupLabel.

perldemo\stackedbar.pl

#!/usr/bin/perl

# The ChartDirector for Perl module is assumed to be in "../lib"
use File::Basename;
use lib (dirname($0)."/../lib") =~ /(.*)/;

use perlchartdir;

# The data for the bar chart
my $data0 = [100, 115, 165, 107, 67];
my $data1 = [85, 106, 129, 161, 123];
my $data2 = [67, 87, 86, 167, 157];

# The labels for the bar chart
my $labels = ["Mon", "Tue", "Wed", "Thu", "Fri"];

# Create a XYChart object of size 600 x 360 pixels
my $c = new XYChart(600, 360);

# Set the plotarea at (70, 20) and of size 400 x 300 pixels, with transparent background and border
# and light grey (0xcccccc) horizontal grid lines
$c->setPlotArea(70, 20, 400, 300, $perlchartdir::Transparent, -1, $perlchartdir::Transparent,
    0xcccccc);

# Add a legend box at (480, 20) using vertical layout and 12pt Arial font. Set background and border
# to transparent and key icon border to the same as the fill color.
my $b = $c->addLegend(480, 20, 1, "Arial", 12);
$b->setBackground($perlchartdir::Transparent, $perlchartdir::Transparent);
$b->setKeyBorder($perlchartdir::SameAsMainColor);

# Set the x and y axis stems to transparent and the label font to 12pt Arial
$c->xAxis()->setColors($perlchartdir::Transparent);
$c->yAxis()->setColors($perlchartdir::Transparent);
$c->xAxis()->setLabelStyle("Arial", 12);
$c->yAxis()->setLabelStyle("Arial", 12);

# Add a stacked bar layer
my $layer = $c->addBarLayer2($perlchartdir::Stack);

# Add the three data sets to the bar layer
$layer->addDataSet($data0, 0xaaccee, "Server # 1");
$layer->addDataSet($data1, 0xbbdd88, "Server # 2");
$layer->addDataSet($data2, 0xeeaa66, "Server # 3");

# Set the bar border to transparent
$layer->setBorderColor($perlchartdir::Transparent);

# Enable labelling for the entire bar and use 12pt Arial font
$layer->setAggregateLabelStyle("Arial", 12);

# Enable labelling for the bar segments and use 12pt Arial font with center alignment
$layer->setDataLabelStyle("Arial", 10)->setAlignment($perlchartdir::Center);

# For a vertical stacked bar with positive data, the first data set is at the bottom. For the legend
# box, by default, the first entry at the top. We can reverse the legend order to make the legend
# box consistent with the stacked bar.
$layer->setLegendOrder($perlchartdir::ReverseLegend);

# Set the labels on the x axis.
$c->xAxis()->setLabels($labels);

# For the automatic y-axis labels, set the minimum spacing to 40 pixels.
$c->yAxis()->setTickDensity(40);

# Add a title to the y axis using dark grey (0x555555) 14pt Arial Bold font
$c->yAxis()->setTitle("Y-Axis Title Placeholder", "Arial Bold", 14, 0x555555);

# Output the chart
$c->makeChart("stackedbar.png");