Side Label Layout

This example demonstrates the "side label layout" method for positioning the sector labels. It also demonstrates metallic background colors, and sector labels with glass shading effect and rounded corners.

With "side label layout", the sector labels are positioned on the left and right sides of the chart. In contrast, all previous examples use "circular label layout", in which the labels are positioned circularly around the pie.

"Side label layout" has the advantages that the labels will automatically shift up and down to avoid overlapping. In the above chart, there are a number of small sectors at the bottom-right of the pie. Note that the labels are shifted to avoid overlapping.

The golden background is achieved by using perlchartdir::goldColor to create the golden color, then use it in PieChart.PieChart as the chart background color.
Similarly, the pink metallic background for the chart title is achieved by using perlchartdir::metalColor to create the pink metallic color, then use Box.setBackground of the title TextBox object to set it as the background color.
The side label layout method is specified with PieChart.setLabelLayout.
The glass shading effect of the sector labels is defined using perlchartdir::glassEffect, then applied to the sector labels using Box.setBackground of the sector label prototype object (obtained via PieChart.setLabelStyle).
The rounded corners of the sector labels are configured using Box.setRoundedCorners of the sector label prototype object.

This example demonstrates a technique for further improving label layout by adjusting the start angle of the first sector using PieChart.setStartAngle.

If the data have a lot of small values and are sorted, the small sectors will be crowded together. For these cases, label layout will be optimal (with the least shifting required) if the small sectors are at the left or right side of the pie, rather than at the top or bottom.

If the data are in descending order (like this example), a start angle of 135 degrees with clockwise sector layout can be used to put the small sectors at approximately 45 - 135 degrees (the right side of the pie). If the data are in ascending order, a start angle of 45 degrees with clockwise sector layout can be used to achieve similar effects.

perldemo\sidelabelpie.pl

#!/usr/bin/perl

# The ChartDirector for Perl module is assumed to be in "../lib"
use File::Basename;
use lib (dirname($0)."/../lib") =~ /(.*)/;

use perlchartdir;

# The data for the pie chart
my $data = [35, 30, 25, 7, 6, 5, 4, 3, 2, 1];

# The labels for the pie chart
my $labels = ["Labor", "Production", "Facilities", "Taxes", "Misc", "Legal", "Insurance",
    "Licenses", "Transport", "Interest"];

# Create a PieChart object of size 560 x 270 pixels, with a golden background and a 1 pixel 3D
# border
my $c = new PieChart(560, 270, perlchartdir::goldColor(), -1, 1);

# Add a title box using 15pt Times Bold Italic font and metallic pink background color
$c->addTitle("Project Cost Breakdown", "Times New Roman Bold Italic", 15)->setBackground(
    perlchartdir::metalColor(0xff9999));

# Set the center of the pie at (280, 135) and the radius to 110 pixels
$c->setPieSize(280, 135, 110);

# Draw the pie in 3D with 20 pixels 3D depth
$c->set3D(20);

# Use the side label layout method
$c->setLabelLayout($perlchartdir::SideLayout);

# Set the label box background color the same as the sector color, with glass effect, and with 5
# pixels rounded corners
my $t = $c->setLabelStyle();
$t->setBackground($perlchartdir::SameAsMainColor, $perlchartdir::Transparent,
    perlchartdir::glassEffect());
$t->setRoundedCorners(5);

# Set the border color of the sector the same color as the fill color. Set the line color of the
# join line to black (0x0)
$c->setLineColor($perlchartdir::SameAsMainColor, 0x000000);

# Set the start angle to 135 degrees may improve layout when there are many small sectors at the end
# of the data array (that is, data sorted in descending order). It is because this makes the small
# sectors position near the horizontal axis, where the text label has the least tendency to overlap.
# For data sorted in ascending order, a start angle of 45 degrees can be used instead.
$c->setStartAngle(135);

# Set the pie data and the pie labels
$c->setData($data, $labels);

# Output the chart
$c->makeChart("sidelabelpie.png");