Contour Chart

This example demonstrates creating a contour chart.

The contour chart is created by adding a ContourLayer to the chart using XYChart.addContourLayer.
ContourLayer.setContourLabelStyle and ContourLayer.setContourLabelFormat are used to configure the contour label.
By default, grid lines are drawn at the background of the plot area and so are behind all chart layers. In this example, PlotArea.moveGridBefore is used to move the grid lines in front of the contour layer.
The color axis (visually represented as the color legend) is positioned vertically to the right of the plot area using ContourLayer.setColorAxis.

perldemo\contour.pl

#!/usr/bin/perl

# The ChartDirector for Perl module is assumed to be in "../lib"
use File::Basename;
use lib (dirname($0)."/../lib") =~ /(.*)/;

use perlchartdir;

# The x and y coordinates of the grid
my $dataX = [-10, -9, -8, -7, -6, -5, -4, -3, -2, -1, 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10];
my $dataY = [-10, -9, -8, -7, -6, -5, -4, -3, -2, -1, 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10];

# The values at the grid points. In this example, we will compute the values using the formula z = x
# * sin(y) + y * sin(x).
my $dataZ = [(0) x (scalar(@$dataX) * scalar(@$dataY))];
for(my $yIndex = 0; $yIndex < scalar(@$dataY); ++$yIndex) {
    my $y = $dataY->[$yIndex];
    for(my $xIndex = 0; $xIndex < scalar(@$dataX); ++$xIndex) {
        my $x = $dataX->[$xIndex];
        $dataZ->[$yIndex * scalar(@$dataX) + $xIndex] = $x * sin($y) + $y * sin($x);
    }
}

# Create a XYChart object of size 600 x 500 pixels
my $c = new XYChart(600, 500);

# Add a title to the chart using 15 points Arial Bold Italic font
$c->addTitle("z = x * sin(y) + y * sin(x)      ", "Arial Bold Italic", 15);

# Set the plotarea at (75, 40) and of size 400 x 400 pixels. Use semi-transparent black (80000000)
# dotted lines for both horizontal and vertical grid lines
$c->setPlotArea(75, 40, 400, 400, -1, -1, -1, $c->dashLineColor(0x80000000, $perlchartdir::DotLine),
    -1);

# Set x-axis and y-axis title using 12 points Arial Bold Italic font
$c->xAxis()->setTitle("X-Axis Title Place Holder", "Arial Bold Italic", 12);
$c->yAxis()->setTitle("Y-Axis Title Place Holder", "Arial Bold Italic", 12);

# Set x-axis and y-axis labels to use Arial Bold font
$c->xAxis()->setLabelStyle("Arial Bold");
$c->yAxis()->setLabelStyle("Arial Bold");

# When auto-scaling, use tick spacing of 40 pixels as a guideline
$c->yAxis()->setTickDensity(40);
$c->xAxis()->setTickDensity(40);

# Add a contour layer using the given data
my $layer = $c->addContourLayer($dataX, $dataY, $dataZ);

# Move the grid lines in front of the contour layer
$c->getPlotArea()->moveGridBefore($layer);

# Add a color axis (the legend) in which the top left corner is anchored at (505, 40). Set the
# length to 400 pixels and the labels on the right side.
my $cAxis = $layer->setColorAxis(505, 40, $perlchartdir::TopLeft, 400, $perlchartdir::Right);

# Add a title to the color axis using 12 points Arial Bold Italic font
$cAxis->setTitle("Color Legend Title Place Holder", "Arial Bold Italic", 12);

# Set color axis labels to use Arial Bold font
$cAxis->setLabelStyle("Arial Bold");

# Output the chart
$c->makeChart("contour.png");