ChartDirector 7.0 (ASP/COM/VB Edition)
Vector Chart
Source Code Listing
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")
' The (x, y) coordinates of the starting point of the vectors
dataX = Array(20, 40, 60, 80, 100, 20, 40, 60, 80, 100, 20, 40, 58, 62, 80, 100, 20, 40, 60, 80, _
100, 20, 40, 60, 80, 100)
dataY = Array(20, 20, 20, 20, 20, 40, 40, 40, 40, 40, 60, 60, 60, 60, 60, 60, 80, 80, 80, 80, 80, _
100, 100, 100, 100, 100)
' The lengths (radii) and directions (angles) of the vectors
dataR = Array(6, 6, 9, 6, 6, 6, 9, 12, 9, 6, 9, 12, 12, 12, 12, 9, 6, 9, 12, 9, 6, 6, 6, 9, 6, 6)
dataA = Array(-45, -30, 0, 30, 45, -60, -45, 0, 45, 60, -90, -90, -90, 90, 90, 90, -120, -135, _
180, 135, 120, -135, -150, 180, 150, 135)
' Create a XYChart object of size 450 x 390 pixels
Set c = cd.XYChart(450, 390)
' Set the plotarea at (55, 40) and of size 350 x 300 pixels, with a light grey border (0xc0c0c0).
' Turn on both horizontal and vertical grid lines with light grey color (0xc0c0c0)
Call c.setPlotArea(55, 40, 350, 300, -1, -1, &Hc0c0c0, &Hc0c0c0, -1)
' Add a title to the chart using 18pt Times Bold Itatic font.
Call c.addTitle("Vector Chart Demonstration", "Times New Roman Bold Italic", 18)
' Add a title to the y axis using 12pt Arial Bold Italic font
Call c.yAxis().setTitle("Y Axis Title", "Arial Bold Italic", 12)
' Add a title to the x axis using 12pt Arial Bold Italic font
Call c.xAxis().setTitle("X Axis Title", "Arial Bold Italic", 12)
' Set the axes line width to 3 pixels
Call c.xAxis().setWidth(3)
Call c.yAxis().setWidth(3)
' Add a vector layer to the chart using blue (0000CC) color, with vector arrow size set to 11 pixels
Call c.addVectorLayer(dataX, dataY, dataR, dataA, cd.YAxisScale, &H0000cc).setArrowHead(11)
' Output the chart
Set viewer = cd.WebChartViewer(Request, "chart1")
Call viewer.setChart(c, cd.SVG)
' Include tool tip for the chart
viewer.ImageMap = c.getHTMLImageMap("", "", _
"title='Vector at ({x}, {value}): Length = {len}, Angle = {dir} deg'")
%>
<!DOCTYPE html>
<html>
<head>
<title>Vector Chart</title>
<!-- Include ChartDirector Javascript Library to support chart interactions -->
<script type="text/javascript" src="cdjcv.js"></script>
</head>
<body style="margin:5px 0px 0px 5px">
<div style="font:bold 18pt verdana;">
Vector Chart
</div>
<hr style="border:solid 1px #000080; background:#000080" />
<div style="font:10pt verdana; margin-bottom:1.5em">
<a href="viewsource.asp?file=<%= Request("SCRIPT_NAME") %>">View Chart Source Code</a>
</div>
<!-- ****** Here is the chart image ****** -->
<%= viewer.renderHTML() %>
</body>
</html>Public Sub createChart(viewer As Object, chartIndex As Integer)
Dim cd As New ChartDirector.API
' The (x, y) coordinates of the starting point of the vectors
Dim dataX()
dataX = Array(20, 40, 60, 80, 100, 20, 40, 60, 80, 100, 20, 40, 58, 62, 80, 100, 20, 40, 60, _
80, 100, 20, 40, 60, 80, 100)
Dim dataY()
dataY = Array(20, 20, 20, 20, 20, 40, 40, 40, 40, 40, 60, 60, 60, 60, 60, 60, 80, 80, 80, 80, _
80, 100, 100, 100, 100, 100)
' The lengths (radii) and directions (angles) of the vectors
Dim dataR()
dataR = Array(6, 6, 9, 6, 6, 6, 9, 12, 9, 6, 9, 12, 12, 12, 12, 9, 6, 9, 12, 9, 6, 6, 6, 9, 6,6)
Dim dataA()
dataA = Array(-45, -30, 0, 30, 45, -60, -45, 0, 45, 60, -90, -90, -90, 90, 90, 90, -120, -135, _
180, 135, 120, -135, -150, 180, 150, 135)
' Create a XYChart object of size 450 x 390 pixels
Dim c As XYChart
Set c = cd.XYChart(450, 390)
' Set the plotarea at (55, 40) and of size 350 x 300 pixels, with a light grey border
' (0xc0c0c0). Turn on both horizontal and vertical grid lines with light grey color (0xc0c0c0)
Call c.setPlotArea(55, 40, 350, 300, -1, -1, &Hc0c0c0, &Hc0c0c0, -1)
' Add a title to the chart using 18pt Times Bold Itatic font.
Call c.addTitle("Vector Chart Demonstration", "timesbi.ttf", 18)
' Add a title to the y axis using 12pt Arial Bold Italic font
Call c.yAxis().setTitle("Y Axis Title", "arialbi.ttf", 12)
' Add a title to the x axis using 12pt Arial Bold Italic font
Call c.xAxis().setTitle("X Axis Title", "arialbi.ttf", 12)
' Set the axes line width to 3 pixels
Call c.xAxis().setWidth(3)
Call c.yAxis().setWidth(3)
' Add a vector layer to the chart using blue (0000CC) color, with vector arrow size set to 11
' pixels
Call c.addVectorLayer(dataX, dataY, dataR, dataA, cd.YAxisScale, &H0000cc).setArrowHead(11)
' Output the chart
Set viewer.Picture = c.makePicture()
'include tool tip for the chart
viewer.ImageMap = c.getHTMLImageMap("clickable", "", _
"title='Vector at ({x}, {value}): Length = {len}, Angle = {dir} deg'")
End Sub