3D Bubble Chart (2)

[Web Version (in ASP)] aspdemo\threedbubble2.asp

<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The XYZ points for the bubble chart
dataX0 = Array(170, 300, 1000, 1700)
dataY0 = Array(16, 69, 16, 75)
dataZ0 = Array(52, 105, 88, 140)

dataX1 = Array(500, 1000, 1300)
dataY1 = Array(40, 58, 85)
dataZ1 = Array(140, 202, 84)

' Create a XYChart object of size 540 x 480 pixels
Set c = cd.XYChart(540, 480)

' Set the plotarea at (70, 65) and of size 400 x 350 pixels. Turn on both horizontal and vertical
' grid lines with light grey color (0xc0c0c0)
Call c.setPlotArea(70, 65, 400, 350, -1, -1, cd.Transparent, &Hc0c0c0, -1)

' Add a legend box at (70, 30) (top of the chart) with horizontal layout. Use 12pt Times Bold Italic
' font. Set the background and border color to Transparent.
Call c.addLegend(70, 30, False, "Times New Roman Bold Italic", 12).setBackground(cd.Transparent)

' Add a title to the chart using 18pt Times Bold Itatic font.
Call c.addTitle("Product Comparison Chart", "Times New Roman Bold Italic", 18)

' Add titles to the axes using 12pt Arial Bold Italic font
Call c.yAxis().setTitle("Capacity (tons)", "Arial Bold Italic", 12)
Call c.xAxis().setTitle("Range (miles)", "Arial Bold Italic", 12)

' Set the axes line width to 3 pixels
Call c.xAxis().setWidth(3)
Call c.yAxis().setWidth(3)

' Add (dataX0, dataY0) as a scatter layer with red (ff3333) glass spheres, where the sphere size is
' modulated by dataZ0. This creates a bubble effect.
Call c.addScatterLayer(dataX0, dataY0, "Technology AAA", cd.GlassSphere2Shape, 15, &Hff3333 _
    ).setSymbolScale(dataZ0)

' Add (dataX1, dataY1) as a scatter layer with blue (0000ff) glass spheres, where the sphere size is
' modulated by dataZ1. This creates a bubble effect.
Call c.addScatterLayer(dataX1, dataY1, "Technology BBB", cd.GlassSphere2Shape, 15, &H0000ff _
    ).setSymbolScale(dataZ1)

' Output the chart
Set viewer = cd.WebChartViewer(Request, "chart1")
Call viewer.setChart(c, cd.SVG)

' Include tool tip for the chart
viewer.ImageMap = c.getHTMLImageMap("", "", _
    "title='[{dataSetName}] Range = {x} miles, Capacity = {value} tons, Length = {z} meters'")
%>

<!DOCTYPE html>
<html>
<head>
    <title>3D Bubble Chart (2)</title>
    <!-- Include ChartDirector Javascript Library to support chart interactions -->
    <script type="text/javascript" src="cdjcv.js"></script>
</head>
<body style="margin:5px 0px 0px 5px">
    <div style="font:bold 18pt verdana;">
        3D Bubble Chart (2)
    </div>
    <hr style="border:solid 1px #000080; background:#000080" />
    <div style="font:10pt verdana; margin-bottom:1.5em">
        <a href="viewsource.asp?file=<%= Request("SCRIPT_NAME") %>">View Chart Source Code</a>
    </div>
    <!-- ****** Here is the chart image ****** -->
    <%= viewer.renderHTML() %>
</body>
</html>

[Windows Version (in Visual Basic)] vbdemo\threedbubble2.cls

Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The XYZ points for the bubble chart
    Dim dataX0()
    dataX0 = Array(170, 300, 1000, 1700)
    Dim dataY0()
    dataY0 = Array(16, 69, 16, 75)
    Dim dataZ0()
    dataZ0 = Array(52, 105, 88, 140)

    Dim dataX1()
    dataX1 = Array(500, 1000, 1300)
    Dim dataY1()
    dataY1 = Array(40, 58, 85)
    Dim dataZ1()
    dataZ1 = Array(140, 202, 84)

    ' Create a XYChart object of size 540 x 480 pixels
    Dim c As XYChart
    Set c = cd.XYChart(540, 480)

    ' Set the plotarea at (70, 65) and of size 400 x 350 pixels. Turn on both horizontal and
    ' vertical grid lines with light grey color (0xc0c0c0)
    Call c.setPlotArea(70, 65, 400, 350, -1, -1, cd.Transparent, &Hc0c0c0, -1)

    ' Add a legend box at (70, 30) (top of the chart) with horizontal layout. Use 12pt Times Bold
    ' Italic font. Set the background and border color to Transparent.
    Call c.addLegend(70, 30, False, "timesbi.ttf", 12).setBackground(cd.Transparent)

    ' Add a title to the chart using 18pt Times Bold Itatic font.
    Call c.addTitle("Product Comparison Chart", "timesbi.ttf", 18)

    ' Add titles to the axes using 12pt Arial Bold Italic font
    Call c.yAxis().setTitle("Capacity (tons)", "arialbi.ttf", 12)
    Call c.xAxis().setTitle("Range (miles)", "arialbi.ttf", 12)

    ' Set the axes line width to 3 pixels
    Call c.xAxis().setWidth(3)
    Call c.yAxis().setWidth(3)

    ' Add (dataX0, dataY0) as a scatter layer with red (ff3333) glass spheres, where the sphere size
    ' is modulated by dataZ0. This creates a bubble effect.
    Call c.addScatterLayer(dataX0, dataY0, "Technology AAA", cd.GlassSphere2Shape, 15, &Hff3333 _
        ).setSymbolScale(dataZ0)

    ' Add (dataX1, dataY1) as a scatter layer with blue (0000ff) glass spheres, where the sphere
    ' size is modulated by dataZ1. This creates a bubble effect.
    Call c.addScatterLayer(dataX1, dataY1, "Technology BBB", cd.GlassSphere2Shape, 15, &H0000ff _
        ).setSymbolScale(dataZ1)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", _
        "title='[{dataSetName}] Range = {x} miles, Capacity = {value} tons, Length = {z} meters'")

End Sub