Symbol Line Chart (2)

[Web Version (in ASP)] aspdemo\symbolline2.asp

<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The data for the line chart
data0 = Array(42, 49, 33, 38, 64, 56, 29, 41, 44, 57, 59, 42)
data1 = Array(65, 75, 47, 34, 42, 49, 73, 62, 90, 69, 66, 78)
data2 = Array(36, 28, 25, 28, 38, 20, 22, 30, 25, 33, 30, 24)
labels = Array("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec")

' Create a XYChart object of size 600 x 375 pixels
Set c = cd.XYChart(600, 375)

' Add a title to the chart using 18pt Times Bold Italic font
Call c.addTitle("Product Line Global Revenue", "Times New Roman Bold Italic", 18)

' Set the plotarea at (50, 55) and of 500 x 280 pixels in size. Use a vertical gradient color from
' light blue (f9f9ff) to sky blue (aaccff) as background. Set border to transparent and grid lines
' to white (ffffff).
Call c.setPlotArea(50, 55, 500, 280, c.linearGradientColor(0, 55, 0, 335, &Hf9fcff, &Haaccff), -1, _
    cd.Transparent, &Hffffff)

' Add a legend box at (50, 28) using horizontal layout. Use 10pt Arial Bold as font, with
' transparent background.
Call c.addLegend(50, 28, False, "Arial Bold", 10).setBackground(cd.Transparent)

' Set the x axis labels
Call c.xAxis().setLabels(labels)

' Set y-axis tick density to 30 pixels. ChartDirector auto-scaling will use this as the guideline
' when putting ticks on the y-axis.
Call c.yAxis().setTickDensity(30)

' Set axis label style to 8pt Arial Bold
Call c.xAxis().setLabelStyle("Arial Bold", 8)
Call c.yAxis().setLabelStyle("Arial Bold", 8)

' Set axis line width to 2 pixels
Call c.xAxis().setWidth(2)
Call c.yAxis().setWidth(2)

' Add axis title using 10pt Arial Bold Italic font
Call c.yAxis().setTitle("Revenue in USD millions", "Arial Bold Italic", 10)

' Add a line layer to the chart
Set layer = c.addLineLayer2()

' Set the line width to 3 pixels
Call layer.setLineWidth(3)

' Add the three data sets to the line layer, using circles, diamands and X shapes as symbols
Call layer.addDataSet(data0, &Hff0000, "Quantum Computer").setDataSymbol(cd.CircleSymbol, 9)
Call layer.addDataSet(data1, &H00ff00, "Atom Synthesizer").setDataSymbol(cd.DiamondSymbol, 11)
Call layer.addDataSet(data2, &Hff6600, "Proton Cannon").setDataSymbol(cd.Cross2Shape(), 11)

' Output the chart
Set viewer = cd.WebChartViewer(Request, "chart1")
Call viewer.setChart(c, cd.SVG)

' Include tool tip for the chart
viewer.ImageMap = c.getHTMLImageMap("", "", _
    "title='Revenue of {dataSetName} in {xLabel}: US$ {value}M'")
%>

<!DOCTYPE html>
<html>
<head>
    <title>Symbol Line Chart (2)</title>
    <!-- Include ChartDirector Javascript Library to support chart interactions -->
    <script type="text/javascript" src="cdjcv.js"></script>
</head>
<body style="margin:5px 0px 0px 5px">
    <div style="font:bold 18pt verdana;">
        Symbol Line Chart (2)
    </div>
    <hr style="border:solid 1px #000080; background:#000080" />
    <div style="font:10pt verdana; margin-bottom:1.5em">
        <a href="viewsource.asp?file=<%= Request("SCRIPT_NAME") %>">View Chart Source Code</a>
    </div>
    <!-- ****** Here is the chart image ****** -->
    <%= viewer.renderHTML() %>
</body>
</html>

[Windows Version (in Visual Basic)] vbdemo\symbolline2.cls

Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The data for the line chart
    Dim data0()
    data0 = Array(42, 49, 33, 38, 64, 56, 29, 41, 44, 57, 59, 42)
    Dim data1()
    data1 = Array(65, 75, 47, 34, 42, 49, 73, 62, 90, 69, 66, 78)
    Dim data2()
    data2 = Array(36, 28, 25, 28, 38, 20, 22, 30, 25, 33, 30, 24)
    Dim labels()
    labels = Array("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", _
        "Dec")

    ' Create a XYChart object of size 600 x 375 pixels
    Dim c As XYChart
    Set c = cd.XYChart(600, 375)

    ' Add a title to the chart using 18pt Times Bold Italic font
    Call c.addTitle("Product Line Global Revenue", "timesbi.ttf", 18)

    ' Set the plotarea at (50, 55) and of 500 x 280 pixels in size. Use a vertical gradient color
    ' from light blue (f9f9ff) to sky blue (aaccff) as background. Set border to transparent and
    ' grid lines to white (ffffff).
    Call c.setPlotArea(50, 55, 500, 280, c.linearGradientColor(0, 55, 0, 335, &Hf9fcff, &Haaccff), _
        -1, cd.Transparent, &Hffffff)

    ' Add a legend box at (50, 28) using horizontal layout. Use 10pt Arial Bold as font, with
    ' transparent background.
    Call c.addLegend(50, 28, False, "arialbd.ttf", 10).setBackground(cd.Transparent)

    ' Set the x axis labels
    Call c.xAxis().setLabels(labels)

    ' Set y-axis tick density to 30 pixels. ChartDirector auto-scaling will use this as the
    ' guideline when putting ticks on the y-axis.
    Call c.yAxis().setTickDensity(30)

    ' Set axis label style to 8pt Arial Bold
    Call c.xAxis().setLabelStyle("arialbd.ttf", 8)
    Call c.yAxis().setLabelStyle("arialbd.ttf", 8)

    ' Set axis line width to 2 pixels
    Call c.xAxis().setWidth(2)
    Call c.yAxis().setWidth(2)

    ' Add axis title using 10pt Arial Bold Italic font
    Call c.yAxis().setTitle("Revenue in USD millions", "arialbi.ttf", 10)

    ' Add a line layer to the chart
    Dim layer As LineLayer
    Set layer = c.addLineLayer2()

    ' Set the line width to 3 pixels
    Call layer.setLineWidth(3)

    ' Add the three data sets to the line layer, using circles, diamands and X shapes as symbols
    Call layer.addDataSet(data0, &Hff0000, "Quantum Computer").setDataSymbol(cd.CircleSymbol, 9)
    Call layer.addDataSet(data1, &H00ff00, "Atom Synthesizer").setDataSymbol(cd.DiamondSymbol, 11)
    Call layer.addDataSet(data2, &Hff6600, "Proton Cannon").setDataSymbol(cd.Cross2Shape(), 11)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", _
        "title='Revenue of {dataSetName} in {xLabel}: US$ {value}M'")

End Sub