Surface Projection

[Web Version (in ASP)] aspdemo\surfaceprojection.asp
<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The x and y coordinates of the grid
dataX = Array(0, 1, 2, 3, 4, 5, 6, 7, 8)
dataY = Array(0, 1, 2, 3, 4, 5, 6, 7, 8)

' Use random numbers for the z values on the XY grid
Set r = cd.RanSeries(11)
dataZ = r.get2DSeries(UBound(dataX) + 1, UBound(dataY) + 1, 0.1, 1.9)

' Create a SurfaceChart object of size 680 x 580 pixels
Set c = cd.SurfaceChart(680, 580)

' Set the center of the plot region at (310, 280), and set width x depth x height to 320 x 320 x 240
' pixels
Call c.setPlotRegion(310, 280, 320, 320, 240)

' Set the elevation and rotation angles to 30 and 45 degrees
Call c.setViewAngle(30, 45)

' Set the data to use to plot the chart
Call c.setData(dataX, dataY, dataZ)

' Spline interpolate data to a 80 x 80 grid for a smooth surface
Call c.setInterpolation(80, 80)

' Use semi-transparent black (c0000000) for x and y major surface grid lines. Use dotted style for x
' and y minor surface grid lines.
majorGridColor = &Hc0000000
minorGridColor = c.dashLineColor(majorGridColor, cd.DotLine)
Call c.setSurfaceAxisGrid(majorGridColor, majorGridColor, minorGridColor, minorGridColor)

' Add XY projection
Call c.addXYProjection()

' Set contour lines to semi-transparent white (0x7fffffff)
Call c.setContourColor(&H7fffffff)

' Add a color axis (the legend) in which the left center is anchored at (620, 250). Set the length
' to 200 pixels and the labels on the right side.
Call c.setColorAxis(620, 250, cd.Left, 200, cd.Right)

' Set the x, y and z axis titles using 12 pt Arial Bold font
Call c.xAxis().setTitle("X Title<*br*>Placeholder", "Arial Bold", 12)
Call c.yAxis().setTitle("Y Title<*br*>Placeholder", "Arial Bold", 12)
Call c.zAxis().setTitle("Z Title Placeholder", "Arial Bold", 12)

' Output the chart
Set viewer = cd.WebChartViewer(Request, "chart1")
Call viewer.setChart(c, cd.SVG)
%>

<!DOCTYPE html>
<html>
<head>
    <title>Surface Projection</title>
    <!-- Include ChartDirector Javascript Library to support chart interactions -->
    <script type="text/javascript" src="cdjcv.js"></script>
</head>
<body style="margin:5px 0px 0px 5px">
    <div style="font:bold 18pt verdana;">
        Surface Projection
    </div>
    <hr style="border:solid 1px #000080; background:#000080" />
    <div style="font:10pt verdana; margin-bottom:1.5em">
        <a href="viewsource.asp?file=<%= Request("SCRIPT_NAME") %>">View Chart Source Code</a>
    </div>
    <!-- ****** Here is the chart image ****** -->
    <%= viewer.renderHTML() %>
</body>
</html>