Simple Bar Chart (1)

This example demonstrates the basic steps in creating bar charts.

Create an XYChart object using XYChart.XYChart.
Specify the plot area of the chart using XYChart.setPlotArea. The plot area is the rectangle bounded by the x and y axes. You should leave some margin on the outside of the plot area for axis labels, chart titles, etc.
Specify the labels on the x-axis using Axis.setLabels.
Add a bar layer and specify the data for the bars using XYChart.addBarLayer.
Assign the chart to the WebChartViewer using WebChartViewer.setChart, and insert it to the web page using WebChartViewer.renderHTML. (ASP version)
Generate the chart image using BaseChart.makePicture and assign it to the ChartViewer using ChartViewer.Picture. (VB version)
Generate tool tips for the chart using BaseChart.getHTMLImageMap.

[Web Version (in ASP)] aspdemo\simplebar.asp

<%@ language="vbscript" %>
<%
Set cd = CreateObject("ChartDirector.API")

' The data for the bar chart
data = Array(85, 156, 179.5, 211, 123)

' The labels for the bar chart
labels = Array("Mon", "Tue", "Wed", "Thu", "Fri")

' Create a XYChart object of size 250 x 250 pixels
Set c = cd.XYChart(250, 250)

' Set the plotarea at (30, 20) and of size 200 x 200 pixels
Call c.setPlotArea(30, 20, 200, 200)

' Add a bar chart layer using the given data
Call c.addBarLayer(data)

' Set the labels on the x axis.
Call c.xAxis().setLabels(labels)

' Output the chart
Set viewer = cd.WebChartViewer(Request, "chart1")
Call viewer.setChart(c, cd.SVG)

' Include tool tip for the chart
viewer.ImageMap = c.getHTMLImageMap("", "", "title='{xLabel}: {value} GBytes'")
%>

<!DOCTYPE html>
<html>
<head>
    <title>Simple Bar Chart (1)</title>
    <!-- Include ChartDirector Javascript Library to support chart interactions -->
    <script type="text/javascript" src="cdjcv.js"></script>
</head>
<body style="margin:5px 0px 0px 5px">
    <div style="font:bold 18pt verdana;">
        Simple Bar Chart (1)
    </div>
    <hr style="border:solid 1px #000080; background:#000080" />
    <div style="font:10pt verdana; margin-bottom:1.5em">
        <a href="viewsource.asp?file=<%= Request("SCRIPT_NAME") %>">View Chart Source Code</a>
    </div>
    <!-- ****** Here is the chart image ****** -->
    <%= viewer.renderHTML() %>
</body>
</html>

[Windows Version (in Visual Basic)] vbdemo\simplebar.cls

Public Sub createChart(viewer As Object, chartIndex As Integer)

    Dim cd As New ChartDirector.API

    ' The data for the bar chart
    Dim data()
    data = Array(85, 156, 179.5, 211, 123)

    ' The labels for the bar chart
    Dim labels()
    labels = Array("Mon", "Tue", "Wed", "Thu", "Fri")

    ' Create a XYChart object of size 250 x 250 pixels
    Dim c As XYChart
    Set c = cd.XYChart(250, 250)

    ' Set the plotarea at (30, 20) and of size 200 x 200 pixels
    Call c.setPlotArea(30, 20, 200, 200)

    ' Add a bar chart layer using the given data
    Call c.addBarLayer(data)

    ' Set the labels on the x axis.
    Call c.xAxis().setLabels(labels)

    ' Output the chart
    Set viewer.Picture = c.makePicture()

    'include tool tip for the chart
    viewer.ImageMap = c.getHTMLImageMap("clickable", "", "title='{xLabel}: {value} GBytes'")

End Sub