<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// Function to create the demo charts
function createChart(chartIndex)
{
    // Declare local variables
    var value = 0;
    var m = 0;
    var bgGradient = 0;
    var ringGradient = 0;
    var smoothColorScale = 0;
    var stepColorScale = 0;
    var highLowColorScale = 0;
    var t = 0;

    // The value to display on the meter
    value = 72.3;

    // Create an AngularMeter object of size 250 x 250 pixels with transparent background
    m = cd.AngularMeter(250, 250, cd.Transparent);

    // Set the default text and line colors to dark grey (0x333333)
    m.setColor(cd.TextColor, "0x333333");
    m.setColor(cd.LineColor, "0x333333");

    // Demonstration two different meter scale angles
    if (chartIndex Mod 2 EQ 0) {
        // Center at (125, 125), scale radius = 111 pixels, scale angle -140 to +140 degrees
        m.setMeter(125, 125, 109, -140, 140);
    } else {
        // Center at (125, 125), scale radius = 111 pixels, scale angle -180 to +90 degrees
         m.setMeter(125, 125, 109, -180, 90);
    }

    // Add a black (0x000000) circle with radius 123 pixels as background
    m.addRing(0, 123, "0x000000");

    // Background gradient color from white (0xffffff) at the center to light grey (0xdddddd) at the
    // border
    bgGradient = Array(0, "0xffffff", 0.75, "0xeeeeee", 1, "0xdddddd");
    // Add circle with radius 123 pixels as background using the background gradient
    m.addRing(0, 123, m.relativeRadialGradient(bgGradient, 123));

    // Gradient color for the border to make it silver-like
    ringGradient = Array(1, "0x999999", 0.5, "0xdddddd", 0, "0xffffff", -0.5, "0xdddddd", -1,
        "0x999999");
    // Add a ring between radii 114 and 123 pixels using the silver gradient with a light grey
    // (0xbbbbbb) edge as the meter border
    m.addRing(114, 123, m.relativeLinearGradient(ringGradient, 45, 123), "0xbbbbbb");

    // Meter scale is 0 - 100, with major/minor/micro ticks every 10/5/1 units
    m.setScale(0, 100, 10, 5, 1);

    // Set the scale label style to 15pt Arial Italic. Set the major/minor/micro tick lengths to
    // 12/9/6 pixels pointing inwards, and their widths to 2/1/1 pixels.
    m.setLabelStyle("Arial Italic", 15);
    m.setTickLength(-12, -9, -6);
    m.setLineWidth(0, 2, 1, 1);

    // Demostrate different types of color scales and putting them at different positions
    smoothColorScale = Array(0, "0x3333ff", 25, "0x0088ff", 50, "0x00ff00", 75, "0xdddd00", 100,
        "0xff0000");
    stepColorScale = Array(0, "0x00cc00", 60, "0xffdd00", 80, "0xee0000", 100);
    highLowColorScale = Array(0, "0x00ff00", 70, cd.Transparent, 100, "0xff0000");

    if (chartIndex EQ 0) {
        // Add the smooth color scale at the default position
        m.addColorScale(smoothColorScale);
    } else if (chartIndex EQ 1) {
        // Add the smooth color scale starting at radius 62 with zero width and ending at radius 40
        // with 22 pixels outer width
        m.addColorScale(smoothColorScale, 62, 0, 40, 22);
    } else if (chartIndex EQ 2) {
        // Add the smooth color scale starting at radius 109 with zero width and ending at radius
        // 109 with 12 pixels inner width
        m.addColorScale(smoothColorScale, 109, 0, 109, -12);
    } else if (chartIndex EQ 3) {
        // Add the high/low color scale at the default position
        m.addColorScale(highLowColorScale);
    } else if (chartIndex EQ 4) {
        // Add the smooth color scale at radius 44 with 16 pixels outer width
        m.addColorScale(smoothColorScale, 44, 16);
    } else {
        // Add the step color scale at the default position
        m.addColorScale(stepColorScale);
    }

    // Add a text label centered at (125, 175) with 15pt Arial Italic font
    m.addText(125, 175, "CPU", "Arial Italic", 15, cd.TextColor, cd.Center);

    // Add a readout to some of the charts as demonstration
    if (chartIndex EQ 0 Or chartIndex EQ 2) {
        // Put the value label center aligned at (125, 232), using white (0xffffff) 14pt Arial font
        // on a dark grey (0x222222) background. Set box width to 50 pixels with 5 pixels rounded
        // corners.
        t = m.addText(125, 232, m.formatValue(value, "<*block,width=50,halign=center*>{value|1}"),
            "Arial", 14, "0xffffff", cd.BottomCenter);
        t.setBackground("0x222222");
        t.setRoundedCorners(5);
    }

    // Add a red (0xff0000) pointer at the specified value
    m.addPointer2(value, "0xff0000");

    // Output the chart
    return m.makeSession(GetPageContext(), "chart" & chartIndex);
}

chart0URL = createChart(0);
chart1URL = createChart(1);
chart2URL = createChart(2);
chart3URL = createChart(3);
chart4URL = createChart(4);
chart5URL = createChart(5);

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    White Round Meters
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart0URL#" />
<img src="getchart.cfm?#chart1URL#" />
<img src="getchart.cfm?#chart2URL#" />
<img src="getchart.cfm?#chart3URL#" />
<img src="getchart.cfm?#chart4URL#" />
<img src="getchart.cfm?#chart5URL#" />
</cfoutput>
</body>
</html>