Round Meter

This example demonstrates the basic steps in creating a round meter.

A round meter can be created with the following steps:

Create an AngularMeter object using AngularMeter.AngularMeter. In this example, the background color is set Transparent.
Specify the geometry of the meter scale using AngularMeter.setMeter. This specifies the center, the radius, and the starting and ending angles of the meter scale.
Optionally add a background and/or a border using AngularMeter.addRing.
Set the numeric scale of the meter using BaseMeter.setScale
Optionally configures the label style using BaseMeter.setLabelStyle, the tick length using BaseMeter.setTickLength and the tick width using BaseMeter.setLineWidth.
Optionally add a color scale to the meter using BaseMeter.addColorScale. Whereas the meter scale displays the values with text labels, a color scale represents the values with different colors.
Optionally add additional labels to the meter using BaseChart.addText.
Add a "new style" pointer to the meter using AngularMeter.addPointer2. For compatibility with earlier versions of ChartDirector, classical pointers are still supported using the previous method BaseMeter.addPointer.

[File: cfdemo/roundmeter.cfm]

<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// The value to display on the meter
value = 72.3;

// Create an AngularMeter object of size 250 x 250 pixels with transparent background
m = cd.AngularMeter(250, 250, cd.Transparent);

// Center at (125, 125), scale radius = 111 pixels, scale angle -145 to +145 degrees
m.setMeter(125, 125, 111, -145, 145);

// Add a very light grey (0xeeeeee) circle with radius 123 pixels as background
m.addRing(0, 123, "0xeeeeee");
// Add a grey (0xcccccc) ring between radii 116 and 123 pixels as border
m.addRing(116, 123, "0xcccccc");

// Meter scale is 0 - 100, with major/minor/micro ticks every 10/5/1 units
m.setScale(0, 100, 10, 5, 1);

// Set the scale label style to 15pt Arial Italic. Set the major/minor/micro tick lengths to 12/9/6
// pixels pointing inwards, and their widths to 2/1/1 pixels.
m.setLabelStyle("Arial Italic", 15);
m.setTickLength(-12, -9, -6);
m.setLineWidth(0, 2, 1, 1);

// Add a smooth color scale to the meter
smoothColorScale = Array(0, "0x3333ff", 25, "0x0088ff", 50, "0x00ff00", 75, "0xdddd00", 100,
    "0xff0000");
m.addColorScale(smoothColorScale);

// Add a text label centered at (125, 175) with 15pt Arial Italic font
m.addText(125, 175, "CPU", "Arial Italic", 15, cd.TextColor, cd.Center);

// Add a red (0xff0000) pointer at the specified value
m.addPointer2(value, "0xff0000");

// Output the chart
chart1URL = m.makeSession(GetPageContext(), "chart1");

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Round Meter
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart1URL#" />
</cfoutput>
</body>
</html>