H-Bar Meter Orientation

[File: cfdemo/hbarmeterorientation.cfm]
<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// Function to create the demo charts
function createChart(chartIndex)
{
    // Declare local variables
    var value = 0;
    var barColor = 0;
    var m = 0;
    var alignment = 0;
    var meterYPos = 0;
    var labelYPos = 0;
    var colorScalePos = 0;
    var smoothColorScale = 0;
    var t = 0;

    // The value to display on the meter
    value = 75.35;

    // The bar colors for the meters
    barColor = Array("0x0088ff", "0x00cc00", "0x8833dd", "0xff8800");

    // Create a LinearMeter object of size 260 x 80 pixels with very light grey (0xeeeeee)
    // backgruond and a light grey (0xccccccc) 3-pixel thick rounded frame
    m = cd.LinearMeter(260, 80, "0xeeeeee", "0xcccccc");
    m.setRoundedFrame(cd.Transparent);
    m.setThickFrame(3);

    // This example demonstrates putting the text labels at the top or bottom. This is by setting
    // the label alignment, as well as the scale, color scale and label positions.
    alignment = Array(cd.Top, cd.Top, cd.Bottom, cd.Bottom);
    meterYPos = Array(24, 24, 36, 36);
    labelYPos = Array(65, 65, 16, 16);
    colorScalePos = Array(48, 48, 27, 27);

    // Set the scale region
    m.setMeter(18, meterYPos[chartIndex + 1], 222, 20, alignment[chartIndex + 1]);

    // Set meter scale from 0 - 100, with a tick every 10 units
    m.setScale(0, 100, 10);

    // Add a 5-pixel thick smooth color scale
    smoothColorScale = Array(0, "0x0000ff", 25, "0x0088ff", 50, "0x00ff00", 75, "0xdddd00", 100,
        "0xff0000");
    m.addColorScale(smoothColorScale, colorScalePos[chartIndex + 1], 5);

    // Add a bar from 0 to value with glass effect and 4 pixel rounded corners
    m.addBar(0, value, barColor[chartIndex + 1], cd.glassEffect(cd.NormalGlare, cd.Top), 4);

    //
    // In this example, some charts have the "Temperauture" label on the left side and the value
    // readout on the right side, and some charts have the reverse
    //

    if (chartIndex Mod 2 EQ 0) {
        // Add a label on the left side using 8pt Arial Bold font
        m.addText(15, labelYPos[chartIndex + 1], "Temperature C", "Arial Bold", 8, cd.TextColor,
            cd.Left);

        // Add a text box on the right side. Display the value using white (0xffffff) 8pt Arial Bold
        // font on a black (0x000000) background with depressed rounded border.
        t = m.addText(240, labelYPos[chartIndex + 1], m.formatValue(value, "2"), "Arial", 8,
            "0xffffff", cd.Right);
        t.setBackground("0x000000", "0x000000", -1);
        t.setRoundedCorners(3);
    } else {
        // Add a label on the right side using 8pt Arial Bold font
        m.addText(243, labelYPos[chartIndex + 1], "Temperature C", "Arial Bold", 8, cd.TextColor,
            cd.Right);

        // Add a text box on the left side. Display the value using white (0xffffff) 8pt Arial Bold
        // font on a black (0x000000) background with depressed rounded border.
        t = m.addText(18, labelYPos[chartIndex + 1], m.formatValue(value, "2"), "Arial", 8,
            "0xffffff", cd.Left);
        t.setBackground("0x000000", "0x000000", -1);
        t.setRoundedCorners(3);
    }

    // Output the chart
    return m.makeSession(GetPageContext(), "chart" & chartIndex);
}

chart0URL = createChart(0);
chart1URL = createChart(1);
chart2URL = createChart(2);
chart3URL = createChart(3);

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    H-Bar Meter Orientation
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart0URL#" />
<img src="getchart.cfm?#chart1URL#" />
<img src="getchart.cfm?#chart2URL#" />
<img src="getchart.cfm?#chart3URL#" />
</cfoutput>
</body>
</html>