The First Project

To get a feeling of using ChartDirector, and to verify the ChartDirector development environment is set up properly, we will begin by building a very simple bar chart.

If you have not yet tried the sample programs, it is highly recommended you try them now. Please refer to the Installation section for details. They are very useful for exploring and testing the features of ChartDirector.

[File: cfdemo/simplebar.cfm]

<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// The data for the bar chart
data = Array(85, 156, 179.5, 211, 123);

// The labels for the bar chart
labels = Array("Mon", "Tue", "Wed", "Thu", "Fri");

// Create a XYChart object of size 250 x 250 pixels
c = cd.XYChart(250, 250);

// Set the plotarea at (30, 20) and of size 200 x 200 pixels
c.setPlotArea(30, 20, 200, 200);

// Add a bar chart layer using the given data
c.addBarLayer(data);

// Set the labels on the x axis.
c.xAxis().setLabels(labels);

// Output the chart
chart1URL = c.makeSession(GetPageContext(), "chart1");

// Include tool tip for the chart
imageMap1 = c.getHTMLImageMap("", "", "title='{xLabel}: {value} GBytes'");

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Simple Bar Chart (1)
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart1URL#" usemap="##map1" border="0" />
<map name="map1">#imageMap1#</map>
</cfoutput>
</body>
</html>

The code is explained below:

```
cd = CreateObject("java", "ChartDirector.CFChart");
```
The above code sets up the variable cd to represent the ChartDirector.CFChart class, which is the access point of the ChartDirector API.
```
c = cd.XYChart(250, 250);
```
The first step in creating any chart in ChartDirector is to create the appropriate chart object. In this example, an XYChart object of size 250 x 250 pixels is created. In ChartDirector, XYChart represents any chart that has x-axis and y-axis, such as the bar chart we are drawing.
```
c.setPlotArea(30, 20, 200, 200);
```
The second step in creating a bar chart is to specify where should we draw the bar chart. This is by specifying the rectangle that contains the bar chart. The rectangle is specified by using the (x, y) coordinates of its top-left corner, together with its width and height.

For this simple bar chart, we will use the majority of the chart area to draw the bar chart. We will leave some margin to allow for the text labels on the axis. In the above code, the top-left corner is set to (30, 30), and both the width and height is set to 200 pixels. Since the entire chart is 250 x 250 in size, there will be 20 to 30 pixels margin for the text labels.

Note that ChartDirector uses a pixel coordinate system that is customary for computer screen. The x pixel coordinate is increasing from left to right. The y pixel coordinate is increasing from top to bottom. The origin (0, 0) is at the top-left corner.

For more complex charts which may contain titles, legend box and other things, we can use this method (and other methods) to design the exact layout of the entire chart.
```
c.addBarLayer(data);
```
The above code adds a bar layer to the XYChart. In ChartDirector, any chart type that has x-axis and y-axis is represented as a layer in the XYChart. An XYChart can contain multiple layers. This allows "combination charts" to be created easily by combining different layers on the same chart (eg., a chart containing a line layer on top of a bar layer) .

In the above line of code, the argument is an array of numbers representing the values of the data points.

For simplicity, in this example, the array is filled with hard coded values. In real applications, you may fill the array with dynamic values. You may also create the array from a ColdFusion query column by using the toArray method, like:

data = myQuery["columnName"].toArray();
```
c.xAxis().setLabels(labels);
```
The above code sets the labels on the x-axis. The first method XYChart.xAxis retrieves the Axis object that represents the x-axis. The second method Axis.setLabels binds the text labels to the x-axis. The argument to the setLabels method is an array of text strings.
```
chart1URL = c.makeSession(GetPageContext(), "chart1");
```
Up to this point, the chart is completed. The above code uses BaseChart.makeSession to output the chart image into a session variable called "chart1".

We need to store the image in a session variable because we cannot deliver the image to the browser now. In HTML, we need to send an <IMG> tag to the browser first. The browser will then use the URL in the <IMG> to get the chart image from another HTTP connection.

BaseChart.makeSession returns a URL query that can be used in the <IMG> tag to reference the image (see below).

By default, BaseChart.makeSession outputs in PNG format, which is supported by all major browsers. You may also use other formats (such as GIF and JPG). Please refer to BaseChart.makeSession for details.
```
imageMap1 = c.getHTMLImageMap("", "", "title='{xLabel}: US${value}K'");
```
After creating the chart image, an image map can be created for the chart to configure mouse interactions. In this example, the image map is configured to display tool tips of the format "title='{xLabel}: US${value}K'" when the mouse cursor is on top of the bars.

Note that mouse interactions are optional. Your can always leave out the BaseChart.getHTMLImageMap code if mouse interactions are not required.
```
<img src="getchart.cfm?#chart1URL#" usemap="##map1" border="0" />
<map name="map1">#imageMap1#</map>
```
The <IMG> tag above instructs the browser to load the chart image. The URL of the chart image is getchart.cfm?#chart1URL#. The getchart.cfm is a standard CFM that comes with ChartDirector. It uses the query chart1URL returned by BaseChart.makeSession to retrieve the chart image from the session variable, and delivers it to the browser.

The usemap attribute and the <MAP> tag above instruct the browser to apply the image map to the chart image for providing tool tips support.

Note: The trial version of ChartDirector will include small yellow banners at the bottom of the charts it produces. These banners will disappear in the licensed version of ChartDirector.