<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// Function to create the demo charts
function createChart(chartIndex)
{
    // Declare local variables
    var value = 0;
    var m = 0;
    var title = 0;
    var smoothColorScale = 0;
    var stepColorScale = 0;
    var highLowColorScale = 0;
    var highColorScale = 0;
    var t = 0;

    // The value to display on the meter
    value = 66.77;

    // Create a LinearMeter object of size 70 x 260 pixels with black background and rounded corners
    m = cd.LinearMeter(70, 260, "0x000000");
    m.setRoundedFrame(cd.Transparent);

    // Set the default text and line colors to white (0xffffff)
    m.setColor(cd.TextColor, "0xffffff");
    m.setColor(cd.LineColor, "0xffffff");

    // Set the scale region top-left corner at (36, 30), with size of 20 x 196 pixels. The scale
    // labels are located on the left (default - implies vertical meter).
    m.setMeter(36, 30, 20, 196);

    // Set meter scale from 0 - 100, with a tick every 10 units
    m.setScale(0, 100, 10);

    // Add the chart title at the top center
    title = m.addText(m.getWidth() / 2, 5, "Temp C", "Arial Bold", 8, cd.TextColor, cd.TopCenter);

    // Move the scale labels 8 pixels from the meter scale to make room for the color scale
    m.setLabelPos(False, 8);

    // Demostrate different types of color scales
    smoothColorScale = Array(0, "0x0000ff", 25, "0x0088ff", 50, "0x00ff00", 75, "0xdddd00", 100,
        "0xff0000");
    stepColorScale = Array(0, "0x00dd00", 50, "0xffff00", 80, "0xff0000", 100);
    highLowColorScale = Array(0, "0x0000ff", 40, cd.Transparent, 60, cd.Transparent, 100, "0xff0000"
        );
    highColorScale = Array(70, cd.Transparent, 100, "0xff0000");

    if (chartIndex EQ 0) {
        // Add a blue (0x0088ff) bar from 0 to value with glass effect and 4 pixel rounded corners
        m.addBar(0, value, "0x0088ff", cd.glassEffect(cd.NormalGlare, cd.Left), 4);
        // Add a 4-pixel thick smooth color scale at x = 29 (left of meter scale)
        m.addColorScale(smoothColorScale, 29, 4);
    } else if (chartIndex EQ 1) {
         // Add a yellow (0xCC9922) bar from 0 to value with bar lighting effect
        m.addBar(0, value, "0xcc9922", cd.barLighting());
        // Add a 4-pixel thick smooth color scale at x = 29 (left of meter scale)
        m.addColorScale(smoothColorScale, 29, 4);

        // Set the title style to black text on a yellow (0xcc9922) background with rounded corners
        title.setFontColor("0x000000");
        title.setBackground("0xcc9922");
        title.setRoundedCorners(2);
    } else if (chartIndex EQ 2) {
         // Add a grey (0xaaaaaa) bar from 0 to value with bar lighting effect
        m.addBar(0, value, "0xaaaaaa", cd.barLighting());
        // Add a 4-pixel high/low color scale at x = 29 (left of meter scale)
        m.addColorScale(highLowColorScale, 29, 4);
    } else if (chartIndex EQ 3) {
         // Add a brown (0xbb6622) bar from 0 to value with cylinder lighting effect
        m.addBar(0, value, "0xbb6622", cd.cylinderEffect());
        // Add a 4 pixel thick brown (0xbb6622) frame
        m.setThickFrame(4, "0xbb6622");
        // Add a high only color scale at x = 29 (left of meter scale)
        m.addColorScale(highColorScale, 29, 4);
    } else if (chartIndex EQ 4) {
        // Add a purple (0x7755ee) bar from 0 to value
        m.addBar(0, value, "0x7755ee");
        // Add a 4 pixel thick purple (0x880088) frame
        m.setThickFrame(4, "0x880088");
        // Add a 4-pixel high/low color scale at x = 29 (left of meter scale)
        m.addColorScale(highLowColorScale, 29, 4);
    } else {
         // Add a green (0x00bb00) bar from 0 to value with soft lighting effect and 4 pixel rounded
         // corners
        m.addBar(0, value, "0x00bb00", cd.softLighting(), 4);
        // Add a 4-pixel step color scale at x = 29 (left of meter scale)
        m.addColorScale(stepColorScale, 29, 4);
    }

    // Add a text box at the bottom-center. Display the value using white (0xffffff) 8pt Arial Bold
    // font on a black (0x000000) background with depressed grey (0x333333) rounded border.
    t = m.addText(m.getWidth() / 2, m.getHeight() - 7, m.formatValue(value, "2"), "Arial Bold", 8,
        "0xffffff", cd.BottomCenter);
    t.setBackground("0x000000", "0x333333", -1);
    t.setRoundedCorners(3);

    // Output the chart
    return m.makeSession(GetPageContext(), "chart" & chartIndex);
}

chart0URL = createChart(0);
chart1URL = createChart(1);
chart2URL = createChart(2);
chart3URL = createChart(3);
chart4URL = createChart(4);
chart5URL = createChart(5);

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Black Vertical Bar Meters
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart0URL#" />
<img src="getchart.cfm?#chart1URL#" />
<img src="getchart.cfm?#chart2URL#" />
<img src="getchart.cfm?#chart3URL#" />
<img src="getchart.cfm?#chart4URL#" />
<img src="getchart.cfm?#chart5URL#" />
</cfoutput>
</body>
</html>