Bar Labels

This example extends the Simple Bar Chart (1) example by including bar labels on the bars, and decorating the bars with rounded corners and gradient shading.

Use Layer.setAggregateLabelStyle to include labels on top of the bars. There is an alternative method Layer.setDataLabelStyle for including the labels inside the bars.
Use BarLayer.setRoundedCorners to configure the bars to have rounded corners.
Use Layer.setBorderColor with ChartDirector.CFChart.barLighting to apply a gradient shading effect to the bars.

[File: cfdemo/barlabel.cfm]

<cfscript>

// ChartDirector for ColdFusion API Access Point
cd = CreateObject("java", "ChartDirector.CFChart");

// A utility to allow us to create arrays with data in one line of code
function Array() {
    var result = ArrayNew(1);
    var i = 0;
    for (i = 1; i LTE ArrayLen(arguments); i = i + 1)
        result[i] = arguments[i];
    return result;
}

// The data for the bar chart
data = Array(85, 156, 179, 211, 123, 189, 166);

// The labels for the bar chart
labels = Array("Mon", "Tue", "Wed", "Thu", "Fri", "Sat", "Sun");

// Create a XYChart object of size 600 x 360 pixels
c = cd.XYChart(600, 360);

// Set the plotarea at (70, 20) and of size 500 x 300 pixels, with transparent background and border
// and light grey (0xcccccc) horizontal grid lines
c.setPlotArea(70, 20, 500, 300, cd.Transparent, -1, cd.Transparent, "0xcccccc");

// Set the x and y axis stems to transparent and the label font to 12pt Arial
c.xAxis().setColors(cd.Transparent);
c.yAxis().setColors(cd.Transparent);
c.xAxis().setLabelStyle("Arial", 12);
c.yAxis().setLabelStyle("Arial", 12);

// Add a blue (0x6699bb) bar chart layer using the given data
layer = c.addBarLayer(data, "0x6699bb");

// Use bar gradient lighting with the light intensity from 0.8 to 1.3
layer.setBorderColor(cd.Transparent, cd.barLighting(0.8, 1.3));

// Set rounded corners for bars
layer.setRoundedCorners();

// Display labela on top of bars using 12pt Arial font
layer.setAggregateLabelStyle("Arial", 12);

// Set the labels on the x axis.
c.xAxis().setLabels(labels);

// For the automatic y-axis labels, set the minimum spacing to 40 pixels.
c.yAxis().setTickDensity(40);

// Add a title to the y axis using dark grey (0x555555) 14pt Arial Bold font
c.yAxis().setTitle("Y-Axis Title Placeholder", "Arial Bold", 14, "0x555555");

// Output the chart
chart1URL = c.makeSession(GetPageContext(), "chart1");

// Include tool tip for the chart
imageMap1 = c.getHTMLImageMap("", "", "title='{xLabel}: ${value}M'");

</cfscript>
<html>
<body style="margin:5px 0px 0px 5px">
<div style="font-size:18pt; font-family:verdana; font-weight:bold">
    Bar Labels
</div>
<hr style="border:solid 1px #000080" />
<cfoutput>
<div style="font-size:9pt; font-family:verdana; margin-bottom:1.5em">
    <a href='viewsource.cfm?file=#CGI.SCRIPT_NAME#'>View Source Code</a>
</div>
<img src="getchart.cfm?#chart1URL#" usemap="##map1" border="0" />
<map name="map1">#imageMap1#</map>
</cfoutput>
</body>
</html>